delphi HTTP/HTTPS协议通信 关于 postman

[springworker]

上两个是postman的，我在delphi中怎么调用

[wdonghai]

要是报错的话就一直按，按到有返回结果为止.

procedure TForm1.Button1Click(Sender: TObject);
var
  RequestList : TStringList;
begin
  IdHTTP1.Request.CustomHeaders.Clear;
  IdHTTP1.Request.CustomHeaders.Values['msg-Type']:='GetUserInfoByMeterAdd';
  IdHTTP1.Request.CustomHeaders.Values['AppKey']:='abc';
  IdHTTP1.Request.ContentType:='text/plain';

  RequestList := TStringList.Create;
  RequestList.Add('39060017110803');
  try
    memo1.text:=IdHTTP1.Post('http://153.35.190.198:15578',RequestList);
  except
    on e:exception do
      showmessage(e.Message);
  end;
end;

[wdonghai]

用idhttp这个控件来post的话，老是出错，换wininet函数来弄就很正常.
参考了https://blog.csdn.net/michaeljscofield/article/details/8798803

uses WinInet;

function WebPagePost(sURL,sPostData,sHeader:string):string;
const
  RequestMethod = 'POST';
  HTTP_VERSION  = 'HTTP/1.1';  //HTTP版本 我抓包看过 HTTP/1.0 HTTP/1.1。
var
  dwSize:DWORD;
  SS:TStringStream;
  dwBytesRead:DWORD;
  hInte,hConnection,hRequest:HInternet;
  ContentSize:array[1..1024] of Char;
  HostPort:Integer;
  HostName,FileName:String;
  procedure ParseURL(URL: string;var HostName,FileName:string;var HostPort:Integer);
  var
    i,p,k: Integer;
    function StrToIntDef(const S: string; Default: Integer): Integer;
    var
      E: Integer;
    begin
      Val(S, Result, E);
      if E <> 0 then Result := Default;
    end;
  begin
    if lstrcmpi('http://',PChar(Copy(URL,1,7))) = 0 then System.Delete(URL, 1, 7);
    HostName := URL;
    FileName := '/';
    HostPort := INTERNET_DEFAULT_HTTP_PORT;
    i := Pos('/', URL);
    if i <> 0 then
    begin
      HostName := Copy(URL, 1, i-1);
      FileName := Copy(URL, i, Length(URL) - i + 1);
    end;
    p:=pos(':',HostName);
    if p <> 0 then
    begin
      k:=Length(HostName)-p;
      HostPort:=StrToIntDef(Copy(HostName,p+1,k),INTERNET_DEFAULT_HTTP_PORT);
      Delete(HostName,p,k+1);
    end;
  end;
begin
  Result := '';
  ParseURL(sURL,HostName,FileName,HostPort);
  hInte := InternetOpen('', //UserAgent
                           INTERNET_OPEN_TYPE_PRECONFIG,nil,nil,0);
  if hInte<>nil then
  begin
    hConnection := InternetConnect(hInte,
                                   PChar(HostName),
                                   HostPort,
                                   nil,
                                   nil,
                                   INTERNET_SERVICE_HTTP,
                                   0,
                                   0);
    if hConnection<>nil then
    begin
      hRequest := HttpOpenRequest(hConnection,
                                  PChar(RequestMethod),
                                  PChar(FileName),
                                  HTTP_VERSION,
                                  '', //Referrer 来路
                                  nil,//AcceptTypes 接受的文件类型 TEXT/HTML */*
                                  INTERNET_FLAG_NO_CACHE_WRITE or
                                  INTERNET_FLAG_RELOAD,
                                  0);
      if hRequest<>nil then
      begin
        HttpAddRequestHeaders(hRequest,PChar(sHeader),
                              Length(sHeader),
                              HTTP_ADDREQ_FLAG_ADD or HTTP_ADDREQ_FLAG_REPLACE);
        if HttpSendRequest(hRequest,nil,0,PChar(sPostData),Length(sPostData)) then
        begin
          SS:=TStringStream.Create('');
          try
            dwBytesRead:=1;
            dwSize:=sizeof(ContentSize);
            while dwBytesRead>0 do
            begin
              InternetReadFile(hRequest,@ContentSize,dwsize,dwBytesRead);
              SS.WriteBuffer(ContentSize,dwBytesRead);
            end;
            SetLength(result,SS.size);
            SS.Position:=0;
            SS.ReadBuffer(result[1],SS.Size);
          finally
            SS.Free;
          end;
        end;
      end;
      InternetCloseHandle(hRequest);
    end;
    InternetCloseHandle(hConnection);
  end;
  InternetCloseHandle(hInte);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  sHeader:string;
begin
  sHeader:='Content-Type: text/plain'+#13#10+
           'msg-Type: GetUserInfoByMeterAdd'+#13#10+
           'AppKey: abc';
  memo1.Text:=WebPagePost('http://153.35.190.198:15578','39060017110803',sHeader);
end;