EnumWindowsProc遍历窗体可不可以写到DLL中去

[hdc733]

大虾们：
我现在想把EnumWindowsProc写到DLL中去，遍历窗体后将窗体名称在回传出来。由于功底比较差没能写成功，高手可不可以给予指点一二，万分感激。
function EnumWindowsProc_2(hwnd: HWND; lParam: LPARAM): Boolean; stdcall;
var
buf: array[Byte] of Char;
begin
GetWindowText(hwnd, buf, SizeOf(buf));
Result := True;
end;

[hdc733]

没人知道吗。帮顶一下也好呢

[SupermanTm]

当然可以，只是“将窗体名称回传出来”这个过程你要预先分配好足够大的内存缓冲区，因为DLL中一般是不能用String类型的。

BOOL EnumWindows(
    WNDENUMPROC lpEnumFunc,	// pointer to callback function
    LPARAM lParam 	// application-defined value
   );	

BOOL CALLBACK EnumWindowsProc(
    HWND hwnd,	// handle to parent window
    LPARAM lParam 	// application-defined value
   );	

DLL 中应该这样处理：

library dllTest1;

uses
  Windows,
  SysUtils;

{$R *.res}

type
  TEnumBuff = record
    hTextBuf: PChar;
    FBuffSize: Integer;
    FCount: Integer;
  end;
  PEnumBuff = ^TEnumBuff;

function EnumWindowsProcCB(Wnd: HWND; lParam: Integer): Boolean; stdcall;
var
  X: Integer;
  P: PEnumBuff;
begin
  P:= Pointer(lParam);
  with P^ do begin
    X:= GetWindowText(Wnd, hTextBuf, FBuffSize);
    Result:= (X < FBuffSize);
    if Result and (X <> 0) then begin
      Inc(hTextBuf, X);
      hTextBuf^:= #0;
      Inc(hTextBuf);
      FBuffSize:= FBuffSize - (X+1);
      Inc(FCount);
    end;
  end;
end;

function EnumWindowsNames(lpTextBuf: Pointer; BuffSize: Integer): Integer; stdcall;
var
  FBuff: TEnumBuff;
begin
  Result:= 0;
  with FBuff do begin
    hTextBuf:= lpTextBuf;
    FBuffSize:= BuffSize;
    FCount:= 0;
  end;
  if EnumWindows(@EnumWindowsProcCB, Integer(@FBuff)) then begin
    Result:= FBuff.FCount;
  end;
end;

exports
  EnumWindowsNames name 'EnumWindowsNames';

begin end.

相应的宿主程序：

function EnumWindowsNames(lpTextBuf: Pointer; BuffSize: Integer): Integer; stdcall; external 'dlltest1.dll';

procedure TForm1.Button1Click(Sender: TObject);
var
  P: PChar;
  N: Integer;
  Buf: array [0..8191] of Char;
begin
  P:= @Buf;
  N:= EnumWindowsNames(P, 8192);
  if N <> 0 then repeat
    ListBox1.Items.Add(P);
    Inc(P, StrLen(P) + 1);
    Dec(N);
  until N = 0;
end;