用什么方法可以取得DLL中的函数名？

[lostcity1]

用什么方法可以取得DLL中的函数名？
像DEPENDS.EXE这样。
取出DLL中包含的函数名。

[lovend]

帮你顶

[hyd990214]

其实，你调用他的TLB.pas就可以看到了

[lostcity1]

我试试

谢谢了。

[qinget]

取出DLL中包含的函数名以后呢？如何知道它的调用方法，参数？

[lostcity1]

可以取出了。
谢了。。各位

qinget
你好。
这个方法还不知道。
你有没有可以提供参考的例子啊？
[e-mail]
谢谢

[lw549]

function GetProcList(DllFileName: String): String;
var
DataDirectory: TImageDataDirectory;
P1: ^Cardinal;
Base, NumberOfNames, AddressOfNames, i: Cardinal;
NameList: TStrings;
hModule: Cardinal;
begin
hModule := LoadLibrary(PChar(DllFileName));
NameList := TStringList.Create;
try
DataDirectory :=
PImageNtHeaders(Cardinal(hModule) +
Cardinal(PImageDosHeader(hModule)^._lfanew))^.OptionalHeader.DataDirectory[IMAGE_DIRECTORY_ENTRY_EXPORT];
P1 := Pointer(hModule + DataDirectory.VirtualAddress + 16);
Base := P1^; //输出函数的起始序号。一般为1。
P1 := Pointer(hModule + DataDirectory.VirtualAddress + 24);
NumberOfNames := P1^;//输出函数名的指针的数组中的元素个数。
P1 := Pointer(hModule + DataDirectory.VirtualAddress + 32);
AddressOfNames := P1^; //一个RVA，指向输出函数名的指针的数组。
begin
//lpProcName参数指向函数名
for i := Base to NumberOfNames + Base - 1 do
begin
//按顺序在输出函数名中找
P1 := Pointer(hModule + AddressOfNames + (i - 1) * 4);
NameList.Add(PChar(hModule + P1^)); //当前输出函数名
end;
end;
Result := NameList.DelimitedText;
finally
FreeLibrary(hModule);
NameList.Free;
end;
end;

[lw549]

不过对于那些没有函数名,只有序号的,这个函数没办法,其他工具也没办法找到

[僵哥]

uses
ImageHlp;

procedure ListDLLExports(const FileName: string; List: TStrings);
type
TDWordArray = array [0..$FFFFF] of DWORD;
var
imageinfo: LoadedImage;
pExportDirectory: PImageExportDirectory;
dirsize: Cardinal;
pDummy: PImageSectionHeader;
i: Cardinal;
pNameRVAs: ^TDWordArray;
Name: string;
begin
List.Clear;
if MapAndLoad(PChar(FileName), nil, @imageinfo, True, True) then
begin
try
pExportDirectory := ImageDirectoryEntryToData(imageinfo.MappedAddress,
False, IMAGE_DIRECTORY_ENTRY_EXPORT, dirsize);
if (pExportDirectory <> nil) then
begin
pNameRVAs := ImageRvaToVa(imageinfo.FileHeader, imageinfo.MappedAddress,
DWORD(pExportDirectory^.AddressOfNames), pDummy);
for i := 0 to pExportDirectory^.NumberOfNames - 1 do
begin
Name := PChar(ImageRvaToVa(imageinfo.FileHeader, imageinfo.MappedAddress,
pNameRVAs^[i], pDummy));
List.Add(Name);
end;
end;
finally
UnMapAndLoad(@imageinfo);
end;
end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
List: TStrings;
i: Integer;
s: string;
begin
List := TStringList.Create;
try
ListDLLExports('C:\WINDOWS\SYSTEM32\browseui.dll', List);
ShowMessage(IntToStr(list.Count) + ' functions in dll');
s := 'List of functions:';
for i := 0 to List.Count - 1 do
s := s + #13#10 + List[i];
ShowMessage(S);
finally
List.Free
end;
end;